***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 27, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5241B A K 
.param
+vc0 = 5.006e-11	vc1 = 6.020e-11		vc2 = 1.000		vc3 = 2.025e-12		vc4 = 6.335e-1
+tc1 = 1.021e-2		tc2 = 3.721e-3		tc3 = 1.251e-2		tc4 = 9.001e-3
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 2.694e-15	   n = 1.054		  rs = 4.706e-1
+ibv = 20e-3		 nbv = 1.0		  bv = 11
+ikf = 3.024e-2
***** capacitance parameter *****
+cjo = 3.896e-11	   m = 3.314e-1		  vj = 6.043e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.113		 xti = 3
+trs1 = -3.025e-4	trs2 = 9.925e-6		tikf = 1.0e-2
+tbv1 = 6.145e-4	tbv2 = -6.227e-8	
.ends MMSZ5241B
*$
